Inhalte

# Funktion MAXWENNS

Gibt das Maximum der Werte der Zellen in einem Bereich zurück, die mehrere Bedingungen in mehreren Bereichen erfüllen.

### Syntax

MAXWENNS(Funktionsbereich; Bereich 1; Kriterium 1 [; Bereich 2; Kriterium 2] [; … [; Bereich 127; Kriterium 127]])

Funktionsbereich – erforderliches Argument. Ist ein Zellbereich, der Name eines benannten Bereichs oder eine Spalten-/Zeilenüberschrift, der/die Werte enthält, für die das Maximum berechnet wird.

Bereich 1 – erforderliches Argument. Ist ein Zellbereich, ein Name eines Bereichs oder eine Spalten-/Zeilenbeschriftung, welche(r) die Werte enthält, die bei erfüllter Bedingung gezählt werden sollen.

Kriterium 1: Ein Kriterium ist ein Textausdruck, der aus einem einzelnen Zellbezug, einer Formel, Zahl oder einem Text berechnet wird. Es wird bei Vergleichen mit Zellinhalten verwendet.

Ein Verweis auf eine leere Zelle wird als Zahlenwert 0 interpretiert.

Ein passender Ausdruck kann sein:

- Eine Zahl oder ein logischer Wert. Ein übereinstimmender Zelleninhalt entspricht dem Zahlenwert oder dem logischen Wert.

- Ein Wert, der mit einem Vergleichs-Operator beginnt (<, <=, =, >, >= oder <>).

  Bei = gilt: Wenn der Wert leer ist, stimmt er mit leeren Zellen überein.

  Bei <> gilt: Wenn der Wert leer ist, stimmt er mit nicht leeren Zellen überein.

  Bei <> gilt: Wenn der Wert nicht leer ist, stimmt er mit jedem Zellinhalt außer dem Wert überein, einschließlich leerer Zellen.

  Hinweis: "=0" stimmt nicht mit leeren Zellen überein.

  Für = und <> gilt: Wenn der Wert nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann und die Eigenschaft Suchkriterien = und <> müssen auf ganze Zellen zutreffen aktiviert ist, wird mit dem gesamten Zellinhalt verglichen, wenn nicht aktiviert, wird mit jedem Teil des Felds verglichen, der den Kriterien entspricht. Für = und <> gilt: Wenn der Wert nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann, trifft die Eigenschaft zu.

- Anderer Textwert. Wenn die Eigenschaft Suchkriterien = und <> müssen auf ganze Zellen zutreffen wahr ist, wird der Vergleich mit dem gesamten Zellinhalt durchgeführt, wenn falsch, wird der Vergleich mit jedem Teil des Felds durchgeführt, der den Kriterien entspricht. Der Ausdruck kann Text, Zahlen, reguläre Ausdrücke oder Platzhalter enthalten (falls in den Berechnungsoptionen aktiviert).

Bereich 2 – optional. Für Bereich 2 und folgende gilt dasselbe wie für Bereich 1.

Kriterium 2 – Optional. Kriterium 2 und alle Folgenden bedeutet dasselbe wie Kriterium.

Die Suche unterstützt Platzhalter oder reguläre Ausdrücke. Wenn reguläre Ausdrücke aktiviert sind, können Sie "all.*" eingeben, um beispielsweise das erste Vorkommen von "all", gefolgt von beliebigen Zeichen, zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Metazeichen oder Operator eines regulären Ausdrucks ein "\" voranstellen oder den Text in \Q…\E einschließen. Die automatische Auswertung von Platzhaltern oder regulären Ausdrücken können Sie unter LibreOffice – EinstellungenExtras – Optionen… – LibreOffice Calc – Berechnen umschalten.

Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Suchkriterien-Zeichenfolgen sind, die einen regulären Ausdruck darstellen, besteht der erste Versuch darin, die Zeichenfolgen-Kriterien in Zahlen umzuwandeln. Zum Beispiel wird in bestimmten Gebietsschemen ".0" in "0.0" konvertiert und so weiter. Bei Erfolg handelt es sich bei der Übereinstimmung nicht um eine Übereinstimmung mit regulären Ausdrücken, sondern um eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, in dem das Dezimaltrennzeichen nicht der Punkt ist, funktioniert die Konvertierung regulärer Ausdrücke. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch verstanden werden kann, beispielsweise ".[0]" oder ".\0" oder "(?i).0".

Funktionsbereich und Bereich 1, Bereich 2, … müssen alle dieselbe Größe haben, anderenfalls gibt die Funktion den Fehlerwert Err:502 – ungültiges Argument – zurück.

Die logische Beziehung zwischen Bedingungen kann als logisches UND (Konjunktion) definiert werden. In anderen Worten, wenn und nur wenn alle angegebenen Bedingungen zutreffen, wird ein Wert von der zugehörigen Zelle aus dem angegebenen Funktionsbereich in der Berechnung berücksichtigt.

Die Funktion kann bis zu 255 Argumente verarbeiten, bedeutet, dass Sie 127 Bereiche und Bedingungen festlegen können.

Wenn die Zelle WAHR enthält, wird sie wie 1 behandelt, wenn FALSCH, wie 0 (Null).

### Beispiele

Betrachten Sie folgende Tabelle

| A | B | C
1 | Produktname | Sales | Revenue
2 | Buntstift | 20 | 65
3 | Stift | 35 | 85
4 | Schulbuch | 20 | 190
5 | Buch | 17 | 180
6 | Buntstift-Set | nicht | nicht

In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.

#### Einfache Verwendung

=MAXWENNS(B2:B6;B2:B6;"<35")

Berechnet das Maximum der Werte im Bereich B2:B6, die größer oder gleich 20 sind. Ergibt 35, da die fünfte Zeile die Bedingung nicht erfüllt.

=MAXWENNS(C2:C6;B2:B6;">=20";C2:C6;"<90")

Berechnet das Maximum der Werte im Bereich C2:C6, die kleiner als 90 und deren entsprechende Zellwerte im Bereich B2:B6 größer oder gleich 20 sind. Gibt 85 zurück, da die vierte und fünfte Zeile je mindestens eine Bedingung nicht erfüllen.

#### Verwendung mit regulären Ausdrücken und verschachtelten Funktionen

=MAXWENNS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Berechnet das Maximum der Werte im Bereich C2:C6, die allen Werten im Bereich B2:B6, außer dem Minimum und dem Maximum, entsprechen. Ergibt 190, da nur die vierte Zeile die Bedingungen erfüllt.

=MAXWENNS(C2:C6;A2:A6;".*stift";B2:B6;"<="&MAX(B2:B6))

Berechnet das Maximum der Werte des Bereichs C2:C6, deren zugehörige Zellen des Bereichs A2:A6 auf "stift" enden und mit Ausnahme der Zellen des Bereichs B2:B6, die deren Maximum enthalten. Gibt 85 zurück, da nur die dritte Zeile alle Bedingungen erfüllt.

#### Bezüge zu einer Zelle mit einer Bedingung

Falls Sie eine Bedingung einfach ändern möchten, können Sie diese in einer eigenen Zelle festlegen und einen Bezug zu dieser Zelle in der Bedingung der Funktion MAXWENNS verwenden. Beispielsweise kann die oben stehende Formel wie folgt umgeschrieben werden:

=MAXWENNS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Wenn E2 = "stift" ist, ergibt die Funktion 65, da der Bezug zur Zelle derem Inhalt entspricht.

#### Technische Information

Diese Funktion ist seit LibreOffice 5.2 verfügbar.

Diese Funktion ist NICHT Bestandteil des Standards Open Document-Format für Office-Anwendungen (OpenDocument) Version 1.3. Teil 4: Format für neu berechnete Formeln (OpenFormula). Der Namensraum ist

COM.MICROSOFT.MAXIFS

Verwandte Themen

Englische Wiki-Seite zu MAXWENNS.

MAX, MAXA, MIN, MINA,

ZÄHLENWENNS, MINWENNS, MAXWENNS, MITTELWERTWENNS, SUMMEWENNS

Liste der regulären Ausdrücke